mob1200 ; Elrond Sample Script ; Axel 2002-Sep-30
        q

create  ;
        i $p($$room^comm(me,"M"),",",2)'=101 d
        . d force^comm(me,"say uh, I do not live here!")
        . d force^comm(me,"/purge elrond")
        q

enter   ;
        i $$isnpc^comm(who) q
        d in^comm(1,me,"d delayed^"_$zn_"("_me_","_who_")",0)
        q

attack  ;
purge   ;
        i me=vict d
        . n pl
        . s override=1
        . d force^comm(me,"snick")
        . d cancel^comm(me,1)
        . d sit
        q

trymove ;--- override that someone forces me!
        i who=me s override=1 q
        ;
        ;--- I won't let ppl go up!
        i dir=4&(who'=$$player^comm("axel")) d
        . s override=1
        . d force^comm(me,"stand")
        . d force^comm(me,"emote steps in front of you and won't let you pass.")
        . d cancel^comm(me,1)
        . d sit
        q

sit     ;
        d in^comm(2,me,"d force^comm("_me_","_$c(34)_"sit"_$c(34)_")")
        q

attack  ;
        d cancel^comm(me)
        k telling(me)
        s override=1
        d force^comm(me,"say FU!")
        d in^comm(1,me,"d out^"_$zn_"("_me_","_killer_")",0)
        q

out(me,killer)  ;
        d force^comm(me,"emote throws "_$$name^comm(killer)_" out.")
        d force^comm(killer,"w")
        q

delayed(me,who)
        d start^story(me,$zn,"story",3)
        q

story   ;Xd force^comm(ch,"stand")
        ;Xd force^comm(ch,"emote clears his throat.")
        ;There was in Gondolin a jewel-smith named Enerdhil,
        ;the greatest of that craft among the Noldor after
        ;the death of Fëanor.
        ;Enerdhil loved all green things that grew,
        ;and his greatest joy was to see the sunlight through
        ;the leaves of trees.
        ;And it came into his heart to make a jewel
        ;within which the clear light of the sun should be imprisoned,
        ;but the jewel should be green as leaves.
        ;And he made this thing, and even the Noldor marvelled at it.
        ;Xd force^comm(ch,"bow")
        ;Xd force^comm(ch,"sit")
        ;$